1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
/*
* Written by J.T. Conklin <jtc@NetBSD.org>.
* Public domain.
*/
#include <machine/asm.h>
#if defined(LIBC_SCCS)
RCSID("$NetBSD: strncmp.S,v 1.4 2014/05/22 15:01:57 uebayasi Exp $")
#endif
/*
* NOTE: I've unrolled the loop eight times: large enough to make a
* significant difference, and small enough not to totally trash the
* cache.
*/
ENTRY(strncmp)
testq %rdx,%rdx
jmp L2 /* Jump into the loop! */
L1: incq %rdi
incq %rsi
decq %rdx
L2: jz L4 /* strings are equal */
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
jne L3
incq %rdi
incq %rsi
decq %rdx
jz L4
movb (%rdi),%al
testb %al,%al
jz L3
cmpb %al,(%rsi)
je L1
L3: movzbl (%rdi),%eax /* unsigned comparison */
movzbl (%rsi),%ecx
subl %ecx,%eax
ret
L4: xorl %eax,%eax
ret
END(strncmp)
|
